Squirrel (programming language)

  function factorial(x)
  {
    if (x == 0) {
      return 1;
    }
    else {
      return x * factorial(x-1);
    }
  }

  function not_a_random_number_generator(max) {
    local last = 42;
    local IM = 139968;
    local IA = 3877;
    local IC = 29573;
    for(;;) { // loops forever
      yield (max * (last = (last * IA + IC) % IM) / IM);
    }
  }

  local randtor = not_a_random_number_generator(100);

  for(local i = 0; i < 10; i += 1)
     print(">"+resume randtor+"\n");

  class BaseVector {
    constructor(...)
    {
      if(vargv.len() >= 3) {
        x = vargv[0];
        y = vargv[1];
        z = vargv[2];
      }
    }
    x = 0;
    y = 0;
    z = 0;
  }

  class Vector3 extends BaseVector {
    function _add(other)
    {
      if(other instanceof ::Vector3)
        return ::Vector3(x+other.x,y+other.y,z+other.z);
      else
        throw "wrong parameter";
    }
    function Print()
    {
      ::print(x+","+y+","+z+"\n");
    }
  }

  local v0 = Vector3(1,2,3)
  local v1 = Vector3(11,12,13)
  local v2 = v0 + v1;
  v2.Print();